dialog blizzaro {
  size -1 -1 440 430
  title "Blizzaro - Shoot'em up"
  option pixels notheme
  icon $ico
  button "Shoot", 1, 20 30 400 300
  button "Etat" 2, 20 350 400 60
  button "ok" 17, 0 0 0 0, cancel, hide 
  menu "&Game", 7
  item "&New", 8
  item break, 15  
  item "&Pause", 9
  item "&Resume", 16
  item break, 10
  item "&Quit", 11  
  menu "&Speed", 3
  item "&Slow", 4
  item "&Normal", 5
  item "&Fast", 6
  menu "&Help", 12
  item "&How to play...", 13
  item break, 14
  item "&About Blizzaro...", 15
}
ON *:dialog:blizzaro:menu:11:fermer
ON *:dialog:blizzaro:menu:8:debut-jeu
ON *:dialog:blizzaro:menu:16:resume
ON *:dialog:blizzaro:menu:9:pause
ON *:dialog:blizzaro:menu:4:set %blizzaro_vit 60 
ON *:dialog:blizzaro:menu:5:set %blizzaro_vit 30
ON *:dialog:blizzaro:menu:6:set %blizzaro_vit 1
ON *:close:@blizzaro:fermer
ON *:dialog:blizzaro:menu:13:aide
ON *:dialog:blizzaro:menu:15:credits
ON *:DIALOG:blizzaro:init:0: {
  .disable #joueur  
  window -hp +ef @blizzaro 0 0 506 406
  window -hp +ef @etat 0 0 506 406
  did -b blizzaro 9
  did -b blizzaro 16  
  drawfill -r @etat 0 0 0 0
  drawfill -r @blizzaro 0 0 0 0  
  md_x SetMircVersion $version
  md_x MarkDialog $dname
  md_x SetControlMDX blizzaro 1 Window > $dialo
  did -a $dname 1 grab $window(@blizzaro).hwnd @blizzaro
  md_x SetControlMDX blizzaro 2 Window > $dialo
  did -a $dname 2 grab $window(@etat).hwnd @etat
  drawrect -dr @blizzaro $rgb(255,255,255) 3 170 90 195 175 30 30
  drawrect -dr @blizzaro $rgb(255,255,255) 3 170 90 195 175 20 20
  drawrect -dr @blizzaro $rgb(255,255,255) 3 170 90 195 175 50 50
  texte_acc
  %blizzaro_tmp_ani = 0  
  anim
  .timerblizzaro_ani -om 0 300 anim
}

alias blizzaro { if (!$dialog(blizzaro)) dialog -dom blizzaro blizzaro | dialog -v blizzaro }
alias -l md_x { dll $scriptdirmdx.dll $1- }
alias -l ico return $scriptdirblizzaro.ico
alias -l dat return $scriptdirdat.png
alias -l dialo return $scriptdirdialog.mdx
alias -l copier drawpic -nc @blizzaro $1 $2 $1 $2 $3 $4 %blizzaro_tmp_back_im
alias -l fermer {
  .timerblizzaro_* off
  splay -m stop 
  free-en
  unset %blizzaro_tmp_*
  if ($dialog(blizzaro)) dialog -x blizzaro
}
alias -l pause {
  .disable #joueur  
  .timerblizzaro_bouge -p
  .timerblizzaro_creer -p
  drawpic -ct @blizzaro $rgb(255,0,255) 116 135 58 34 162 37 $dat
  did -e blizzaro 16
  did -b blizzaro 9
}
alias -l resume {
  copier 116 135 162 37
  .timerblizzaro_bouge -r
  .timerblizzaro_creer -r
  .enable #joueur
  did -b blizzaro 16
  did -e blizzaro 9
}
alias -l fin-stage {
  .disable #joueur
  .timerblizzaro_* off
  did -b blizzaro 16
  did -b blizzaro 9 
  drawpic -nc @blizzaro 0 0 %blizzaro_tmp_back_im
  free-en
  %blizzaro_tmp_y = 250
  .timerblizzaro_anim_bat -om  0 50 anim-fin  
  %blizzaro_tmp_y = 258
  splay -m stop
  anim-fin
}
alias -l fin-stage2 {
  if ($hget(blizzaro,stage) < 4) {
    hadd blizzaro stage $calc($hget(blizzaro,stage) + 1)
    debut-stage
  }
  else fin
}
alias -l fin {
  drawfill -r @blizzaro 0 50 0 0  
  %blizzaro_tmp_ani = 0  
  anim
  .timerblizzaro_ani -om 0 300 anim
  drawrect -nrd @blizzaro $rgb(255,255,255) 2 20 10 358 120 20 20
  drawline -nr @blizzaro 0 2 233 129 253 129
  drawline -nr @blizzaro $rgb(255,255,255) 2 233 129 184 159
  drawline -nr @blizzaro $rgb(255,255,255) 2 253 129 184 159
  drawtext -nr @blizzaro $rgb(255,255,255) arial 16 40 20 Congratulation !
  drawtext -nr @blizzaro $rgb(255,255,255) arial 16 40 50 You've destroyed the invaders and you've
  drawtext -nr @blizzaro $rgb(255,255,255) arial 16 40 70 saved the planet Blizzaro.
  drawtext -nbpr @blizzaro $rgb(255,255,255) 0 arial 16 40 100 See you on www.blizzard.be.tf ...
  drawpic @blizzaro
}
alias -l texte_acc {
  drawpic -t @blizzaro $rgb(255,0,255) 3 10 2 153 390 61 $dat
  drawtext -pbr @blizzaro $rgb(255,255,255) 0 arial 16 233 100 Welcome
  drawtext -r @blizzaro $rgb(255,255,255) arial 16 239 140 To play,
  drawtext -r @blizzaro $rgb(255,255,255) arial 16 240 160 choose
  drawtext -pbr @blizzaro $rgb(255,255,255) 0 arial 16 220 195 Game > New
  drawtext -r @blizzaro $rgb(255,255,255) arial 16 234 226 Have fun !
}
alias -l anim {
  drawpic @blizzaro 20 150 $calc(%blizzaro_tmp_ani * 130) 0 128 100 " $+ $scriptdir $+ ani.png"
  inc %blizzaro_tmp_ani
  if (%blizzaro_tmp_ani == 2) %blizzaro_tmp_ani = 0
}
alias -l debut-jeu {
  .disable #joueur 
  unset %blizzaro_tmp_ani
  .timerblizzaro_* off  
  drawpic -c 
  if ($hget(blizzaro)) hfree blizzaro
  free-en 
  hmake blizzaro 60
  hadd blizzaro score 0
  hadd blizzaro vies 3
  hadd blizzaro stage 1
  hadd blizzaro shoots 0
  hadd blizzaro max 50 
  if (!%blizzaro_vit) %blizzaro_vit = 30 
  init-etat 
  score 0
  if (%blizzaro_high) high %blizzaro_high
  else high 0 
  debut-stage
}
alias -l debut-stage {
  did -b blizzaro 9
  did -b blizzaro 16 
  %blizzaro_tmp_back_im = " $+ $scriptdir $+ back $+ $hget(blizzaro,stage) $+ .jpg"
  drawpic -c @blizzaro 0 0 %blizzaro_tmp_back_im
  free-en
  hadd blizzaro x 170
  drawpic -ntc @blizzaro $rgb(255,0,255) 67 134 3 264 263 40 $dat
  drawpic -nc @blizzaro 270 141 $calc(($hget(blizzaro,stage) - 1) * 45 + $hget(blizzaro,stage) - 1) 306 45 26 $dat
  .timerblizzaro_stage2 -om 1 500 drawpic @blizzaro
  unset %blizzaro_tmp_y*
  %blizzaro_tmp_y = 308
  if ($hget(blizzaro,stage) == 1) hadd blizzaro max 30
  elseif ($hget(blizzaro,stage) == 2) hadd blizzaro max 70
  elseif ($hget(blizzaro,stage) == 3) hadd blizzaro max 110
  elseif ($hget(blizzaro,stage) == 4) hadd blizzaro max 145 
  splay -m " $+ $scriptdir $+ blizzaro.mid"
  .timerblizzaro_anim_bat -om  0 65 anim-bat 
}
alias -l debut-stage2 {
  copier 67 134 263 40
  drawpic @blizzaro
  .did -e blizzaro 9
  .did -b blizzaro 16
  .timerblizzaro_bouge -om 0 %blizzaro_vit bouger
  .timerblizzaro_creer 0 1 creer_enemy
  .enable #joueur
}
alias -l free-en {
  var %i = 0 
  while (%i < 6) {
    if ($hget(enemy $+ %i)) hfree enemy $+ %i
    if ($hget(shoot $+ %i)) hfree shoot $+ %i
    inc %i  
  }
}
alias -l anim-fin {
  copier $hget(blizzaro,x) %blizzaro_tmp_y 56 26
  dec %blizzaro_tmp_y 10   
  drawpic -ntc @blizzaro $rgb(255,0,255) $hget(blizzaro,x) %blizzaro_tmp_y 0 0 56 26 $dat
  drawpic @blizzaro  
  if (%blizzaro_tmp_y <= -25) { .timerblizzaro_anim_bat off | .timerblizzaro_stage -om 1 1000 fin-stage2 }
}
alias -l init-etat {
  drawfill -Nr @etat 0 500 0 0
  drawrect -nrd @etat $rgb(255,255,255) 1 15 13 163 37 20 20
  drawtext -nrpb @etat $rgb(255,255,255) $rgb(0) arial 12 30 6  Life 
  drawtext -nr @etat $rgb(255,255,255) fixedsys 20 220 13 Score
  drawtext -nr @etat $rgb(255,255,255) fixedsys 20 220 33 High
  vies
}
alias -l vies {
  drawtext -nrpb @etat $rgb(255,255,255) $rgb(0) arial 12 30 6  Life 
  drawpic -nts @etat $rgb(255,0,255) 25 25 42 20 0 0 56 26 $dat
  drawpic -nts @etat $rgb(255,0,255) 75 25 42 20 0 0 56 26 $dat
  drawpic -nts @etat $rgb(255,0,255) 125 25 42 20 0 0 56 26 $dat
  if ($1 == 2) drawrect -nfr @etat 0 1 125 25 45 21
  elseif ($1 == 1) { drawrect -nfr @etat 0 1 125 25 45 21 | drawrect -nfr @etat 0 1 75 25 45 21 }
  elseif ($1 == 0) { drawrect -nfr @etat 0 1 125 25 45 21 | drawrect -nfr @etat 0 1 75 25 45 21 | drawrect -nfr @etat 0 1 25 25 45 21 } 
  drawpic @etat
}
alias -l anim-bat {
  copier 170 %blizzaro_tmp_y 56 26
  if (!%blizzaro_tmp_y2) dec %blizzaro_tmp_y 10   
  else inc %blizzaro_tmp_y 10  
  drawpic -ntc @blizzaro $rgb(255,0,255) 170 %blizzaro_tmp_y 0 0 56 26 $dat
  drawpic @blizzaro  
  if (%blizzaro_tmp_y < 218) %blizzaro_tmp_y2 = 1
  if (%blizzaro_tmp_y >= 258) && (%blizzaro_tmp_y2) { .timerblizzaro_anim_bat off | .timerblizzaro_stage -om 1 2000 debut-stage2 }
}
alias -l score {
  var %tmp-score $calc($hget(blizzaro,score) + $1)
  if (%tmp-score < 0) return
  hadd blizzaro score %tmp-score
  var %l $hget(blizzaro,score)
  if (%l < 0) %l = 0  
  var %score 0000000000
  %score = $mid(%score,1,$calc(10 - $len(%l))) $+ %l
  drawtext -br @etat $rgb(255,255,255) 0 fixedsys 20 280 13 %score
  if (%blizzaro_high < %l) { high %l }
}
alias -l high {
  %blizzaro_high = $1
  var %l %blizzaro_high
  var %score 0000000000
  %score = $mid(%score,1,$calc(10 - $len(%l))) $+ %l
  drawtext -br @etat $rgb(255,255,255) 0 fixedsys 20 280 33 %score
}

#joueur on
ON *:dialog:blizzaro:sclick:1: {
  %blizzaro_tmp_mousex = $gettok($did(1),4,32)  
  if ($gettok($did(1),1,32) == Move) {
    if (%blizzaro_tmp_mouse.x != %blizzaro_tmp_mousex) {
      if (%blizzaro_tmp_mousex isnum 28-367) {
        copier 0 258 476 26       
        drawpic -tnc @blizzaro $rgb(255,0,255) $calc(%blizzaro_tmp_mousex - 28) 258 0 0 56 26 $dat
        hadd blizzaro x $calc(%blizzaro_tmp_mousex - 28)        
        drawpic @blizzaro
      }
      elseif (%blizzaro_tmp_mousex < 28) {
        copier 0 258 476 26
        drawpic -ntc @blizzaro $rgb(255,0,255) 0 258 0 0 56 26 $dat
        hadd blizzaro x 0       
        drawpic @blizzaro
      }
      elseif (%blizzaro_tmp_mousex > 367) {
        copier 0 258 476 26
        drawpic -ntc @blizzaro $rgb(255,0,255) 339 258 0 0 56 26 $dat
        hadd blizzaro x 339        
        drawpic @blizzaro      
      }
      %blizzaro_tmp_mouse.x = %blizzaro_tmp_mousex 
    } 
  }
  if ($gettok($did(1),1-3,32) == LButtonDown inside @blizzaro) { shoot }
}
#joueur end
ON *:SIGNAL:shoot_boug: {
  var %i = 1
  while (%i < 6) {
    var %no = enemy $+ %i
    if ($hget(%no)) && ($hget(%no,xp) == 0) && ($onpoly(4,4,$hget(%no,x),$hget(%no,y),$calc($hget(%no,x) + $hget(%no,w)),$hget(%no,y),$calc($hget(%no,x) + $hget(%no,w)),$calc($hget(%no,y) + $hget(%no,h)),$hget(%no,x),$calc($hget(%no,y) + $hget(%no,h)),$hget($1,x),$hget($1,y),$calc($hget($1,x) +14),$hget($1,y),$calc($hget($1,x) +14),$calc($hget($1,y) +14),$hget($1,x),$calc($hget($1,y) +14))) { hadd %no xp 1 | copier $hget($1,x) $hget($1,y) 14 14 | score $hget(%no,s) | hfree $1 | hadd blizzaro max $calc($hget(blizzaro,max) -1) }
    inc %i
  } 
}
alias -l shoot {
  var %i = 1
  while ($hget(shoot $+ %i)) inc %i
  if (%i < 6) { 
    hmake Shoot $+ %i 20
    if (%blizzaro_tmp_mousex isnum 28-367) { hadd Shoot $+ %i x $calc(%blizzaro_tmp_mousex - 5) }
    else { 
      if (%blizzaro_tmp_mousex < 28) { hadd Shoot $+ %i x 23 }
      else hadd Shoot $+ %i x 362
    }
    hadd Shoot $+ %i y 246
    drawpic -tc @blizzaro $rgb(255,0,255) $hget(shoot $+ %i,x) $hget(shoot $+ %i,y) 96 17 13 14 $dat
    hadd blizzaro shoots $calc($hget(blizzaro,shoots) + 1)    
  }
}
alias -l bouger {
  var %i = 1
  while (%i < 6) {
    if ($hget(shoot $+ %i)) {
      var %prec_y = $hget(shoot $+ %i,y)
      var %tmp_x $hget(shoot $+ %i,x)   
      hadd shoot [ $+ [ %i ] ] y $calc(%prec_y - 14)
      var %tmp_y $hget(shoot $+ %i,y)
      drawpic -nc @blizzaro %tmp_x %prec_y %tmp_x %prec_y 14 14 %blizzaro_tmp_back_im
      drawpic -ntc @blizzaro $rgb(255,0,255) %tmp_x %tmp_y 96 17 14 14 $dat
      drawpic @blizzaro    
      if (%tmp_y < -10) { hfree Shoot $+ %i }  
      else .signal shoot_boug shoot $+ %i
    }
    if ($hget(enemy $+ %i)) move %i
    inc %i    
  }
  .timerblizzaro_bouge -om 0 %blizzaro_vit bouger
}
alias -l creer_enemy {
  var %i = 0
  while ($hget(enemy $+ %i)) inc %i
  if (%i < 6) {
    var %w = 0, %h = 0, %x = 0, %y = 0, %s = 0 
    var %nb = $rand(1,100)
    if (%nb isnum 1-25) { %w = 31 | %h = 32 | %x = 1 | %y = 61 | %s = 30 }    
    elseif (%nb isnum 26-50) { %w = 22 | %h = 32 | %x = 1 | %y = 27 | %s = 50 }    
    elseif (%nb isnum 51-65) { %w = 29 | %h = 32 | %x = 25 | %y = 30 | %s = 100 }
    elseif (%nb isnum 66-78) { %w = 33 | %h = 31 | %x = 58 | %y = 1 | %s = 150 }
    elseif (%nb == 79 ) { %w = 29 | %h = 31 | %x = 111 | %y = 1 | %s = 10 * $hget(blizzaro,shoots) }          
    else { %w = 21 | %h = 30 | %x = 35 | %y = 65 | %s = 65 }
    var %no enemy $+ %i
    hmake %no 70
    hadd %no x $rand(28,360)
    hadd %no y -42
    hadd %no w %w
    hadd %no h %h
    hadd %no dx %x
    hadd %no dy %y
    hadd %no v $calc($rand(3,12) + $hget(blizzaro,stage))
    hadd %no s %s      
    hadd %no xp 0 
  }
}
alias -l move {
  var %nom enemy $+ $1
  var %tp_y = $hget(%nom,y)
  if ($hget(%nom,xp) == 0) {
    hadd %nom y $calc($hget(%nom,y) + $hget(%nom,v))
    var %pos-y = $calc(%tp_y + $hget(%nom,v))     
    copier $hget(%nom,x) %tp_y $hget(%nom,w) $hget(%nom,h)  
    drawpic -ntc @blizzaro $rgb(255,0,255) $hget(%nom,x) %pos-y $hget(%nom,dx) $hget(%nom,dy) $hget(%nom,w) $hget(%nom,h) $dat
    if (%pos-y > 230) && ($onpoly(4,4,$hget(%nom,x),$hget(%nom,y),$calc($hget(%nom,x) + $hget(%nom,w)),$hget(%nom,y),$calc($hget(%nom,x) + $hget(%nom,w)),$calc($hget(%nom,y) + $hget(%nom,h)),$hget(%nom,x),$calc($hget(%nom,y) + $hget(%nom,h)),$hget(blizzaro,x),258,$calc($hget(blizzaro,x) +56),258,$calc($hget(blizzaro,x) +56),284,$hget(blizzaro,x),284)) { explosion }    
    if (%pos-y > 300) { score $calc(0 - 2 * $hget(%nom,s)) | hfree %nom }
  }
  else {
    var %place $calc($hget(%nom,x) - 12)    
    copier %place %tp_y 48 48
    drawpic -ntc @blizzaro $rgb(255,0,255) %place %tp_y $calc($hget(%nom,xp) * 48 - 48) 105 48 48 $dat
    hadd %nom xp $calc($hget(%nom,xp) +1)
    if ($hget(%nom,xp) == 6) { copier %place %tp_y 48 48 | hfree %nom | if ($hget(blizzaro,max) <= 0) fin-stage }   
  }
  drawpic @blizzaro
}
alias -l explosion {
  .disable #joueur
  .timerblizzaro_* off
  drawpic -c @blizzaro 0 0 %blizzaro_tmp_back_im
  splay -m stop
  free-en
  %blizzaro_tmp_xplo = 0
  .timerblizzaro_xplos -om 0 100 xplose 
}
alias -l xplose {
  if (%blizzaro_tmp_xplo >= 4) { .timerblizzaro_xplos off | copier $calc($hget(blizzaro,x) +5) 248 48 48 | .timerblizzaro_xplos -om 1 800 fin_explosion }
  copier $calc($hget(blizzaro,x) +5) 248 48 48 
  drawpic -ntc @blizzaro $rgb(255,0,255) $calc($hget(blizzaro,x) +5) 248 $calc( %blizzaro_tmp_xplo * 48) 105 48 48 $dat
  drawpic @blizzaro 
  inc %blizzaro_tmp_xplo
}
alias -l fin_explosion {
  hadd blizzaro vies $calc($hget(blizzaro,vies) - 1)
  if ($hget(blizzaro,vies) >= 0) { vies $hget(blizzaro,vies) | debut-stage }
  else game-over
}
alias -l game-over {
  .disable #joueur
  .timerblizzaro_* off
  vies 0  
  splay -m stop  
  drawpic -nc @blizzaro 0 0 %blizzaro_tmp_back_im
  drawpic -ntc @blizzaro $rgb(255,0,255) 30 130 2 217 336 44 $dat
  drawpic @blizzaro  
  free-en
  did -b blizzaro 9
  did -b blizzaro 16
}

dialog bliz_aide {
  title "Blizzaro - How to play ?"
  size -1 -1 500 464
  option pixels notheme
  icon $ico
  edit "" 1, 10 10 480 295, multi, vsbar, autovs, read 
  button "points", 2, 10 315 480 90
  button "&Ok", 3, 210 420 80 30, ok
}
on *:dialog:bliz_aide:init:*: {
  dialog -o bliz_aide  
  window -hp +ef @bliz_aide 0 0 506 406
  drawfill -r @bliz_aide 0 0 0 0  
  md_x SetMircVersion $version
  md_x SetMircVersion $version
  md_x MarkDialog $dname
  md_x SetControlMDX $dname 2 Window > $dialo
  did -a $dname 2 grab $window(@bliz_aide).hwnd @bliz_aide
  md_x SetColor $dname 1 background 0
  md_x SetColor $dname 1 textbg 0
  md_x SetColor $dname 1 text $rgb(255,255,255) 
  md_x SetFont 1 14 400 Arial
  drawpic -ntc @bliz_aide $rgb(255,0,255) 20 10 1 61 31 32 $dat 
  drawpic -ntc @bliz_aide $rgb(255,0,255) 24 47 1 27 22 32 $dat
  drawpic -ntc @bliz_aide $rgb(255,0,255) 178 12 35 65 21 30 $dat
  drawpic -ntc @bliz_aide $rgb(255,0,255) 175 48 25 30 29 32 $dat
  drawpic -ntc @bliz_aide $rgb(255,0,255) 335 11 58 1 33 31 $dat
  drawpic -ntc @bliz_aide $rgb(255,0,255) 338 50 111 1 29 31 $dat
  drawtext -nr @bliz_aide $rgb(255,255,255) arial 14 60 17 = 30 points
  drawtext -nr @bliz_aide $rgb(255,255,255) arial 14 60 57 = 50 points
  drawtext -nr @bliz_aide $rgb(255,255,255) arial 14 213 57 = 100 points
  drawtext -nr @bliz_aide $rgb(255,255,255) arial 14 213 17 = 65 points
  drawtext -nr @bliz_aide $rgb(255,255,255) arial 14 380 17 = 150 points
  drawtext -nr @bliz_aide $rgb(255,255,255) arial 14 380 57 = ??? points
  drawpic @bliz_aide
  loadbuf 472-510 -oip bliz_aide 1 " $+ $scriptdir $+ blizzaro.mrc"
}
alias aide {
  var %tempo $dialog(bliz_aide,bliz_aide)
}
alias -l credits {
  var %cred $dialog(credits,credits)
}
dialog credits {
  title "About Blizzaro"
  size -1 -1 130 171
  option dbu notheme
  icon $ico  
  box "Credits", 1, 10 5 110 89
  text "Coding :", 2, 20 20 39 8
  text "Music :", 3, 20 32 25 8
  text "Enemies' sprites, explodes, shoots :", 4, 20 44 49 15
  text "Other sprites, texts :", 5, 20 75 54 8
  text "Backgrounds :", 6, 20 63 35 8
  box "Infos", 7, 10 100 110 46
  text "Contact :", 8, 20 110 22 8
  text "Website :", 9, 20 122 25 8
  link "www.blizzard.be.tf", 10, 50 122 46 8
  link "blizzard@be.tf", 11, 50 110 37 8
  button "Ok", 12, 45 153 40 12, ok
  text "Epsilon", 13, 80 20 25 8
  text "Epsilon", 14, 80 63 25 8
  text "Epsilon", 15, 80 75 25 8
  text "Shibaken", 16, 80 32 25 8
  text "From the game SubSpace", 17, 80 44 36 16
  text "Epsilon - June 2002", 18, 20 134 48 10
}
ON *:DIALOG:credits:init:0:dialog -o credits
ON *:DIALOG:credits:sclick:10:run www.blizzard.be.tf
ON *:DIALOG:credits:sclick:11:run mailto://blizzard@be.tf 
ON *:LOAD: {
  if ($version < 6.0) { echo -s /!\ your mIRC's version is too old ( $+ $version $+ ). this game needs mIRC 6.0 or higher. | unload -rs blizzaro.mrc }
  elseif ($numtok($scriptdir,32) > 1) { echo -s /!\ Sorry but the dir of the game must ( $+ $scriptdir $+ ) cannot have space in it. Please re-install in a dir with no space in the name. (eg: C:\mIRC:\Blizzaro\) | unload -rs blizzaro.mrc }
  else { echo -a *** Blizzaro (shoot'em up), made by Epsilon | echo -a *** Type /blizzaro to play, or use the menubar. }
}
-=Intro=-

Blizzaro is a "shoot'em up" so you have to destroy all the enemies coming from the up of the window.
There is a main dialog, with menus, a game window and a status window.


-=System requirements=-

Pentium II CPU (or higher).
32Mo RAM (or mores).
A soundcard able to play MIDI.

---> NB : The speed of the game depand of your CPU. So you could need to use the  
"Speed" menu to adapt the speed. With a Pentium II, "Fast" is better, and with a Pentium 4, 
"Slow" or "Normal" <--- 


-=How to play=-

To move your spaceship you need to use a mouse. Mouse must be on the game window to be able to move.

To shoot, you just need to click the left button. Since the laser gun need to reload, you cannot have more than 5 shoots at the same time on the screen.

An enemy ship is destroyed if he's hit by a shoot. You get points by destructing them, you can see how many delow.
A rumor tells that there is a very rare enemy... will you fight him ?

To clear a stage, you need to shoot a certain number of ships. Here's how many for each stages :

Stage 1 : 30
Stage 2 : 70
Stage 3 : 110
Stage 4 : ???

If you're hit by a ship, you loose one life. If the counter reach zero, the game is over. 

Have fun !!!
