alias -l dlg dialog $iif($dialog($1),-v,-m $+ $2 $1) $1
alias -l dlgx var %i = $0 | while (%i) { var %d = $ [ $+ [ %i ] ] | if ($dialog(%d)) dialog -x %d | dec %i }
alias -l pxget return $px.get(pxmsm,$$1)
alias -l pxset px.set pxmsm $1-
alias -l pxmsm.get return $readini($scriptdirpxmsm.cfg,n,$1,$2)
alias -l pxmsm.set $iif($3 != $null,writeini,remini) -n $+(",$scriptdirpxmsm.cfg,") $$1-
alias -l pxmsm.hfile return $+(",$scriptdirpxmsm-help.cfg,")
alias -l pxmsm.server { var %. = @pxmsm._servs, %f = $+(",$readini($mircini,files,servers),"), %d = pxmsm.sserv, %i = 1, %s | if (!$dialog(%d)) return | if ($window(%.)) window -c %. | window -hkl %. | filter -fw %f %. n*= $+ $1- $+ :* | did -r %d 3 | if (!$line(%.,0)) { did -ab %d 3 (No servers found) | goto end } | else did -e %d 3 | while ($line(%.,%i)) { %s = $ifmatch | did -a %d 3 $gettok($ifmatch,$iif($numtok(%s,58) == 4,2,3),58) | inc %i } | did -z %d 3 | :end | window -c %. }
alias -l pxmsm.connect { var %d = $iif($3,$3,$did(pxmsm,5).seltext), %. = $pxmsm.get(%d,connopts), %_ = $$iif($1,$1,$did(pxmsm,2).seltext) $$iif($2,$2,$pxmsm.get(%d,port)) %d | server $iif($gettok(%.,1,32) == 2,$iif($gettok(%.,2,32),-n,-m)) $$iif($1,$1,$did(pxmsm,2).seltext) $$iif($2,$2,pxmsm.get(%d,port)) -i $pxmsm.get(%d,nick) $pxmsm.get(%d,anick) $pxmsm.get(%d,email) $pxmsm.get(%d,name) $iif($pxmsm.get(%d,aj),-j $pxmsm.get(%d,chans)) | addrec %_ }
alias -l pxmsm.remrec { var %i = 0 | while ($pxget(n $+ %i)) { pxset n $+ %i | inc %i } }
alias -l sbuf { var %i = 0, %n = $did(pxmsm,5).seltext | did -r pxmsm 2 | while ($pxmsm.get(%n,%i)) { if ($pxmsm.get(%n,%i) != $chr(160)) did -a pxmsm 2 $ifmatch | inc %i } | did -b $dname 8,12 | did -z $dname 2 }
alias -l fspecs { var %d = pxmsm.set $did(pxmsm,5).seltext | %d nick $readini($mircini,mirc,nick) | %d anick $readini($mircini,mirc,anick) | %d email $emailaddr | %d name $readini($mircini,mirc,user) | %d port 6667 | %d connect 0 | %d connopts 2 0 }
alias -l fchk { var %- = $did(pxmsm,5).seltext | if (($pxmsm.get(%-,nick)) && ($pxmsm.get(%-,anick)) && ($pxmsm.get(%-,email)) && ($pxmsm.get(%-,name)) && ($pxmsm.get(%-,port))) return 1 }
alias -l chkdlg { if (!$dialog(pxmsm)) { var %x = $input(The main configuration dialog must be open for this function to work.,228) | if ($1) dialog -x $1 | halt } }
alias -l chknick { if ($regex($remove($1,`,_,^,$chr(91),$chr(93),$chr(123),$chr(125),$chr(124)),^[0-9]|[[:punct:]])) { var %x = $input(You have specified an erroneous nickname and/or alternate nickname. Please try a different one. $+ $+($crlf,$crlf) $+ Note: Nicknames cannot begin with numbers and cannot contain non-alphanumeric characters (!@$#?* etc...).,516,$px.addon) | halt } }
alias -l hwindow { scid $1 | var %s = $iif($window(status window).state == hidden,-w,-h), %i = 1 | while ($window(*,%i)) { window %s $+(",$ifmatch,") | inc %i } }
alias -l dynm { if ($1 == rec) { if ($2 == begin) return $gettok($pxget(n0),1,59) | if ($2 isnum 1-6) { if (!$pxget(n $+ $2)) return - | return $pxget(n $+ $2) } | if ($2 == end) return Clear all: pxmsm.remrec } | elseif ($1 == nw) { if ($2 isnum) { if (!%i) var %i = $cid | return $scon($2).network : hwindow $scon($2) } | if ($2 == end) return test: echo -a %i } }
alias -l addrec { var %n = 0, %. = @pxmsm._tmp | if ($window(%.)) window -c %. | window -hkl %. | while ($pxget(n $+ %n)) { aline %. $ifmatch | inc %n } | if ($fline(%.,$+($1,:,pxmsm.connect $1-3),1)) goto end | if (%n <= 4) { pxset n $+ %n $+($1,:,pxmsm.connect $1-3) | goto end } | iline %. 1 $+($1,:,pxmsm.connect $1-3) | dline %. 6 | %n = 1 | while ($line(%.,%n)) { pxset n $+ $calc(%n - 1) $ifmatch | inc %n } | :end | window -c %. }

dialog pxmsm {
  title $px.nam
  size -1 -1 117 124
  option dbu

  button "&Ende", 1, 4 109 39 12, ok

  combo 5, 3 12 68 50, drop  
  list 2, 3 44 69 62, size extsel vsbar
  text "Server:", 3, 3 36 24 8
  text "Netzwerk:", 4, 3 4 23 8
  button "&Neu...", 6, 75 12 39 11
  button "&Entfernen", 7, 75 25 39 11
  text "¯¯¯¯¯¯¯¯¯¯¯¯¯", 10, 75 59 40 3, disable
  button "&Editiere...", 9, 75 45 39 11
  button "V&erbinde...", 8, 75 63 39 11, disable
  text "¯¯¯¯¯¯¯¯¯¯¯¯¯", 13, 75 76 40 3, disable
  button "N&eu...", 11, 75 81 39 11
  button "En&tfernen", 12, 75 94 39 11, disable
}
on *:dialog:pxmsm:*:*: {
  if ($devent == init) { didtok $dname 5 32 $pxget(networks) | did -c $dname 5 $iif($pxget(curr) <= $did(5).lines && $pxget(curr),$ifmatch,1) | sbuf | if (!$did(5).lines) did -b $dname 7,8,9,10,11,12 }
  if ($devent == sclick) {
    if ($did == 1) { if ($dialog(pxmsm.especs)) || ($dialog(pxmsm.add)) halt | pxset curr $did(5).sel }
    if ($did == 2) { did -e $dname 12 | did $iif($did(2,0).sel == 1,-e,-b) $dname 8 }
    if ($did == 5) sbuf
    if ($did == 6) { var %x = $$remove($dialog(pxmsm.nadd,pxmsm.nadd,-4),$chr(32)) | if (!$dialog(pxmsm)) || ($istok($didtok(5,32),%x,32)) return | did -a $dname 5 %x | pxset networks $addtok($pxget(networks),%x,32) | pxmsm.set %x $calc($ini($scriptsidrpxmsm.cfg,$did(5).seltext,0) + 1) $chr(160) | did -c $dname 5 $did(5).lines | pxset curr $did(5).sel | did -e $dname 7,9,11 | sbuf }
    if ($did == 7) && ($input(Dies entfernt $+(",$did(5).seltext,") vom $px.addon $+ . Dies schliesst sämliche Einstellungen und Verbindungen ein.  $+ $+($crlf,$crlf) $+ Möchtest Du fortfahren?,136,$px.addon)) { pxmsm.set $did(5).seltext | pxset networks $deltok($pxget(networks),$did(5).sel,32) | did -r $dname 2 | did -d $dname 5 $did(5).sel | pxset curr $did(5).sel | did -c $dname 5 1 | did $iif(!$did(5),-b,-e) $dname 7,8,9,11,12 | sbuf }
    if ($did == 8) { pxset curr $did(5).sel | $iif($pxmsm.get($did(5).seltext,connect), pxmsm.connect, $dialog(pxmsm.conn,pxmsm.conn)) }
    if ($did == 9) dlg pxmsm.especs
    if ($did == 11) dlg pxmsm.add
    if ($did == 12) && ($input(Bist Du Dir sicher den ausgewählten Server dauerhaft zu entfernen?,136,$px.addon)) { :l | if ($did(2,1).sel) { did -d $dname 2 $ifmatch | goto l } | did -z $dname 2 | var %n = 0, %i = 1, %d = pxmsm.set $did(5).seltext | while ($did(2,%i)) { %d %n $ifmatch | inc %n | inc %i } | while ($pxmsm.get($did(5).seltext,%n)) { %d %n | inc %n } | did -b $dname 8,12 }
  }
}

dialog pxmsm.conn {
  title $px.addon - Verbindung
  size -1 -1 113 96
  option dbu

  button "&OK", 1, 4 81 37 12, ok
  button "&Abbruch", 6, 72 81 37 12, cancel

  check "Nutze diese Einstellung für die nächste Verbindung.", 9, 5 3 104 10  
  box "Verbindungsoption", 2, 4 14 105 63
  radio "Verbinde über b&estehende Verbindung", 3, 11 26 92 10
  radio "Verbinde über &neue Verbindung", 4, 11 38 86 10
  check "Verbinde nicht s&ofort", 5, 27 49 79 10
  text "Port:", 7, 12 62 11 8
  edit "", 8, 26 60 28 11, autohs center
}
on *:dialog:pxmsm.conn:*:*: {
  if ($devent == init) { var %i = $pxmsm.get($did(pxmsm,5).seltext,connopts) | if ($gettok(%i,1,32) == 1) did -c $dname 3 | else { did -c $dname 4 | did -e $dname 5 } | if ($gettok(%i,2,32)) did -c $dname 5 | did -a $dname 8 $iif($pxmsm.get($did(pxmsm,5).seltext,port),$ifmatch,6667) }
  if ($devent == sclick) { if ($did isnum 3-4) did $iif($did == 3,-b,-e) $dname 5 | if ($did == 1) { if (!$did(8)) { var %x = $input(Please specify a port.,516,$px.addon) | halt } | var %d = $did(pxmsm,5).seltext | pxmsm.set %d connopts $iif($did(3).state,1,2) $did(5).state | pxmsm.set %d port $$did(8) | pxmsm.set %d connect $did(9).state | pxmsm.connect } }
}

dialog pxmsm.especs {
  title
  size -1 -1 115 126
  option dbu

  button "&OK", 1, 4 111 37 12, ok
  button "&Abbruch", 2, 74 111 37 12, cancel

  tab "Channel", 19, 3 2 108 104
  text "Channel:", 3, 9 32 28 8, tab 19
  list 4, 8 40 53 62, tab 19 size vsbar
  button "&Neu...", 5, 64 41 35 11, tab 19
  button "&Löschen", 6, 64 54 35 11, disable tab 19
  button "&Up", 16, 64 77 35 11, disable tab 19
  button "D&own", 17, 64 90 35 11, disable tab 19
  check "&Auto-join channels beim verbinden", 21, 8 19 89 10, tab 19

  tab "Verschiedenes", 20
  check "Benutze folgende Einstellungen beim verbinden.", 18, 8 19 93 10, tab 20
  text "Nick:", 8, 11 44 14 8, tab 20
  edit "", 9, 37 42 63 11, tab 20 autohs limit 30
  edit "", 11, 37 55 63 11, tab 20 autohs limit 30
  text "Alt. Nick:", 10, 11 57 23 8, tab 20
  text "E-mail:", 12, 11 70 16 8, tab 20
  edit "", 13, 37 68 63 11, tab 20 autohs
  text "Name:", 14, 11 83 16 8, tab 20
  edit "", 15, 37 81 63 11, tab 20 autohs
}
on *:dialog:pxmsm.especs:*:*: {
  if ($devent == init) { var %n = $did(pxmsm,5).seltext | dialog -t $dname $px.addon - Edit Specifications ( $+ %n $+ ) | if (!$fchk) fspecs | didtok $dname 4 44 $pxmsm.get(%n,chans) | did -a $dname 9 $pxmsm.get(%n,nick) | did -a $dname 11 $pxmsm.get(%n,anick) | did -a $dname 13 $pxmsm.get(%n,email) | did -a $dname 15 $pxmsm.get(%n,name) | if ($pxmsm.get(%n,connect)) did -c $dname 18 | if ($pxmsm.get(%n,aj)) did -c $dname 21 | else did -b $dname 4,5,6,16,17 }
  if ($devent == sclick) {
    if ($did == 1) { chkdlg $dname | var %x = pxmsm.set $did(pxmsm,5).seltext, %n = $did(pxmsm,5).seltext | %x chans $didtok(4,44) | chknick $did(9) return | %x nick $remove($iif($did(9),$ifmatch,$pxmsm.get(%n,nick)),$chr(32)) | chknick $did(11) | %x anick $remove($iif($did(11),$ifmatch,$pxmsm.get(%n,anick)),$chr(32)) | %x email $iif($did(13),$ifmatch,$pxmsm.get(%n,email)) | %x name $iif($did(15),$ifmatch,$pxmsm.get(%n,name)) | %x connect $did(18).state | %x aj $did(21).state }
    if ($did == 4) { did -e $dname 6 | did $iif($did(4).lines > 1,-e,-b) $dname 16,17 }
    if ($did == 5) { var %x = $$remove($input(Channel name:,193,$px.addon,$chr(35)),$chr(32)) | if ($left(%x,1) != $chr(35)) && ($left(%x,1) != $chr(43)) && ($left(%x,1) != $chr(38)) %x = $chr(35) $+ %x | if ($istok($didtok(4,44),%x,44)) || ($len(%x) == 1) return | did -a $dname 4 %x | did -z $dname 4 }
    if ($did == 6) { var %n = $$did(4).sel | did -d $dname 4 %n | did -z $dname 4 | if (!$did(4).lines) did -b $dname 6 | if ($did(4).lines <= 1) did -b $dname 16,17 | did -c $dname 4 $iif(%n > 1,$calc(%n - 1),1) }
    if ($did == 16) { var %n = $$did(4).sel | if (%n == 1) return | did -i $dname 4 $calc(%n - 1) $did(4,%n) | did -d $dname 4 $calc(%n + 1) | did -c $dname 4 $calc(%n - 1) }  
    if ($did == 17) { var %n = $$did(4).sel | if (%n == $did(4).lines) return | did -i $dname 4 $calc(%n + 2) $did(4,%n) | did -d $dname 4 %n | did -c $dname 4 $calc(%n + 1) }  
    if ($did == 21) did $iif($did(21).state,-e,-b) $dname $+(4,$chr(44),5,$iif($did(4).sel,$chr(44) $+ 6),$iif($did(4).lines > 1 && $did(4).sel,$+($chr(44),16,$chr(44),17)))
  }
}

dialog pxmsm.add {
  title $px.addon - Neu
  size -1 -1 139 41
  option dbu

  button "&OK", 1, 4 26 37 12, ok
  button "&Abbruch", 2, 47 26 37 12, cancel

  text "Server:", 3, 4 4 18 8
  edit "", 4, 4 12 131 11, autohs
  button "&Server...", 5, 98 26 37 12
}
on *:dialog:pxmsm.add:*:*: {
  if ($devent == init) did -f $dname 4
  if ($devent == sclick) {
    if ($did == 1) { chkdlg $dname | var %d = pxmsm, %t = $$remove($did(4),$chr(32)), %tt, %- = $did(%d,5).seltext, %i = 1 | if (!$fchk) fspecs | while ($gettok(%t,%i,44)) { %tt = $ifmatch | if ($istok($didtok(%d,2,32),%tt,32)) goto r | did -a %d 2 %tt | pxmsm.set %- $calc($did(%d,2).lines - 1) %tt | :r | inc %i } }
    if ($did == 5) { chkdlg | did -ra $dname 4 $$dialog(pxmsm.sserv,pxmsm.sserv,-4) } 
  }
}

dialog pxmsm.sserv {
  title $px.addon - Server...
  size -1 -1 115 102
  option dbu

  button "&Auswahl", 2, 77 32 35 12, disable ok  
  button "&Abbruch", 1, 77 86 35 12, cancel

  list 3, 3 31 72 68, size vsbar extsel
  text "Server:", 4, 4 23 21 8
  text "", 5, 1000 1000 0 0, result
  text "Netzwerk:", 6, 4 2 23 8
  combo 7, 3 10 71 50, edit drop
  button "Suchen", 8, 77 10 35 12, hide
}
on *:dialog:pxmsm.sserv:*:*: { 
  if ($devent == init) { did -a $dname 7 (All) | didtok $dname 7 32 $pxget(networks) | did -c $dname 7 $iif($didwm(7,$did(pxmsm,5).seltext),$ifmatch,1) | pxmsm.server $did(7).seltext }
  if ($devent == sclick) {
    if ($did == 3) { var %i = 1, %t | while ($did(3,%i).sel) { %t = $addtok(%t,$did(3,$ifmatch),44) | inc %i } | did -a $dname 5 %t | did -e $dname 2 }
    if ($did == 7) || ($did == 8) pxmsm.server $iif($did(7) != (all),$ifmatch,*)
    did -t $dname $iif($did != 7,2,8)
  }
  if ($devent == dclick) && ($did == 3) dialog -k $dname
  if ($devent == edit) && ($did == 7) did -t $dname 8
}

dialog pxmsm.nadd {
  title "Neues Netzwerk"
  size -1 -1 102 41
  option dbu

  text "Gebe Netzwerk:", 1, 4 3 37 8
  combo 2, 4 12 94 60, edit drop result

  button "&OK", 3, 5 26 37 12, ok
  button "&Abbruch", 4, 60 26 37 12, cancel
}
on *:dialog:pxmsm.nadd:init:*: { var %i = 12, %s, %l | while ($server(%i).group) { %l = $ifmatch | if (%s != %l) did -a $dname 2 %l | %s = %l | inc %i } }

dialog pxmsm-help {
  title $px.nam - Hilfe
  size -1 -1 200 136
  option dbu
  text "Topic:", 2, 5 4 17 7
  list 5, 5 13 70 102, size
  text "Details:", 4, 80 4 18 7
  edit "", 7, 80 13 115 102, read multi vsbar
  button "&Ende", 6, 80 120 40 12, ok
}
on *:dialog:pxmsm-help:*:*: {
  if ($devent == init) { if (!$isfile($px.help)) goto empty | loadbuf -ottopics $dname 5 $px.help | if (!$did(5).lines) { :empty | did -ab $dname 5 Empty! | did -a $dname 7 No help topics could be found. | return } | did -a $dname 7 Select a topic you wish to find help on. }
  if ($devent == sclick) && ($did == 5) { did -r $dname 7 | if (!$readini($px.help,$did(5).seltext,n0)) did -a $dname 7 No help is available for $+(",$did(5).seltext,".) | elseif (!$readini($px.help,$did(5).seltext,n1)) did -a $dname 7 $readini($px.help,$did(5).seltext,n0) | else { var %n = 0 | while ($readini($px.help,$did(5).seltext,$+(n,%n))) { did -a $dname 7 $ifmatch $+ $iif($readini($px.help,$did(5).seltext,$+(n,$calc(%n + 1))),$+($crlf,$crlf)) | inc %n } | did -c $dname 7 1 } }
}

on *:CONNECT: px.reg
on *:DISCONNECT: unset %px.using
;on *:LOAD: { if ($version > 6) { .write -c $+(",$scriptdirpxmsm.cfg,") | px.echo -ae $px.nam(1) loaded. (by $px(3) < $+ $px(4) $+ >) | px.reg | px.about } }
on *:START:{ if ($version < 6.01) { px.echo -ae $px.nam(1) requires mIRC 6.01 or higher. Visit http://www.mirc.com/ for the latest version of mIRC. | $+($px(9),.unload) $px.nam } }
on *:UNLOAD: { px.set pxmsm | var %f = $+(",$scriptdirpxmsm.cfg,") | if ($isfile(%f)) .remove -b %f | dlgx pxmsm pxmsm.especs pxmsm.sserv pxmsm-help | px.unreg | px.echo -ae $px.nam(1) unloaded successfully. }

alias -l px.about %px.scr = $px(8) | dlg ProjectX
alias -l px.acq return $gettok($read($1,$calc($2 + 1)),3-,32)
alias -l px.nfo var %. = did -a projectx | %. 7 $px.acq($1-,3) | %. 9 $px.acq($1-,4) | %. 11 $remove($px.acq($1-,2),v) - (Base v $+ $px.acq($1-,9) $+ ) | %. 13 $px.acq($1-,5) | %. 15 $px.acq($1-,7)
alias -l px.get return $readini(projectx.ini,$1,$$2)
alias -l px return $gettok($read($+(",$script,"),$calc($1 + 1)),3-,32)
alias -l px.nam return $remove($gettok($px(1),2-,32),[,]) $iif($1,$px(2))
alias -l px.addon return $gettok($px.nam,2-,32)
alias -l px.echo echo $color(info) $1 $px.lp $2-
alias -l px.lp return $iif($isalias(pxt.lp),$pxt.lp,***)
alias -l px.using return ProjectX %px.using (12 $+ $px(6) $+ )
alias -l px.set $iif($3 != $null,writeini,remini) projectx.ini $$1-
alias -l px.www if ($+(",$readini($mircini,files,browser),")) run $ifmatch $$1-
alias -l px.reg if ($server) %px.using = %px.using $+ $iif(%px.using,$chr(44)) $px.addon $+ ( $+ $px(2) $+ )
alias -l px.unreg if ($remtok(%px.using,$matchtok(%px.using,$px.addon,1,44),44)) %px.using = $ifmatch | else unset %px.using
alias -l px.help return $+(",$replace($script,.mrc,-help.cfg),")
alias -l px.rm return $replace($script,mrc,txt)
alias -l px.readme $iif($isfile($px.rm),run $px.rm,px.echo -a Could not locate $nopath($px.rm))
alias -l px.win {
  var %px = drawline -r @px | window -fph +d @px 0 0 276 122 | drawrect -fr @px 0 0 0 0 276 122 | var %i = 0, %x, %y, %m = mIRC Scripting Crew | while (%i < 81) { %x = $calc(147 + %i) | %y = $calc(22 + %i) | %px 4210752 1 %x %y $calc(32 + %x) %y | %px 6316128 1 $calc(1 + %x) $calc(%y - 1) $calc(33 + %x) $calc(%y - 1) | %x = $calc(227 - %i) | %px 4210752 1 %x %y $calc(32 + %x) %y | %px 6316128 1 $calc(1 + %x) $calc(%y - 1) $calc(33 + %x) $calc(%y - 1) | inc %i 4 }
  %px 4210752 1 18 62 193 62 | %px 6316128 1 18 61 193 61 | %px = drawtext -r @px | %px 4210752 arial 27 15 34 Project | %px 4210752 arial 27 16 33 Project | %px 6316128 arial 27 17 32 Project | %i = 0 | %x = 28 | %y = 78 | while (%i < 42) { %px $rgb(%i,%i,%i) arial 14 %x %y %m | dec %y | inc %x | inc %i 3 } | %px 6052956 arial 14 40 65 %m | drawsave @px $+(",$scriptdirpx.bmp,") | window -c @px
}
on *:dialog:projectx:init:0: if (%px.scr == $px(8)) { did -a $dname 2,16,19 $str(¯,49) | if (!$isfile($px.rm)) did -b $dname 20 | var %. = $replace($script,mrc,png), %` , %- | if (!$isfile(%.)) px.win | did -g $dname 1 $+(",$iif($isfile(%.),%.,$scriptdirpx.bmp),") | %. = $script(0) | while (%.) { %` = $script(%.) | %- = $nopath(%`) | if ($left(%-,2) == px) { %- = $remove($gettok($px.acq(%`,1),2-,32),[,],ProjectX) | did -i $dname 5 1 %- ( $+ $nopath(%`) $+ ) | if (%` == $script) px.nfo %` } | dec %. } | did -c $dname 5 $didwm(5,$px.addon *,1) }
on *:dialog:projectx:sclick:*: {
  if (%px.scr == $px(8)) {
    var %- = $script($remove($gettok($did(5).seltext,2,40),$chr(41))), %. = $script(0), %px.readme = $replace(%-,mrc,txt) | while (%.) { if ($script(%.) == %-) { %- = $ifmatch | %. = 1 } | dec %. }
    if ($did == 5) { did $iif($isfile(%px.readme),-e,-b) $dname 20 | %. = $replace(%-,mrc,png) | if (!$isfile(%.)) px.win | did -rg $dname 1 $+(",$iif($isfile(%.),%.,$scriptdirpx.bmp),") | px.nfo %- }
    if ($did == 9) px.www $+(mailto:,$did(9),?subject=,$remove($gettok($px.acq(%-,1),2-,32),[,]) $px.acq(%-,2)) | if ($did == 18) px.www $px(6) | if ($did == 20) .run %px.readme | if ($did == 21) unset %px.scr
  }
}
dialog projectx {
  title "ProjectX Addon Information"
  size -1 -1 153 193
  option dbu
  icon 1, 7 7 138 61
  text "", 2, 3 76 147 3,disable
  text " Information ", 3, 6 73 31 7
  text "Addon:", 4, 14 84 19 7
  combo 5, 46 83 100 71,drop
  text "Author:", 6, 14 98 19 7
  text "", 7, 46 98 99 7
  text "E-mail:", 8, 14 108 16 7
  link "", 9, 46 108 99 8
  text "Version:", 10, 14 118 20 7
  text "", 11, 46 118 99 7
  text "Updated:", 12, 14 128 23 7
  text "", 13, 46 128 99 7
  text "Extra Info:", 14, 14 138 27 7
  text "", 15, 46 138 99 14
  text "", 16, 3 155 147 3,disable
  text "The ProjectX Website:", 17, 13 160 54 8
  link $px(6), 18, 71 160 69 7
  text "", 19, 3 171 147 3,disable
  button "&Read Me", 20, 5 177 37 12
  button "&OK", 21, 111 177 37 12,cancel
}
